Outros sites Medialivre
Caldeirão da Bolsa

Sistema de trading "Tromba Rija"

Espaço dedicado a todo o tipo de troca de impressões sobre os mercados financeiros e ao que possa condicionar o desempenho dos mesmos.

por Crómio » 7/4/2008 9:19

Cem,

Se isto não foi uma lição... epá prontos, não se discute isso!
Não senhor, isto não foi nenhuma lição!

Obrigado pela partilha de conhecimento.

Um Abraço
There are two kinds of investors: those who don't know where the market is headed, and those who don't know that they don't know.

William Bernstein
Avatar do Utilizador
 
Mensagens: 2745
Registado: 2/11/2007 16:52

por Pata-Hari » 7/4/2008 8:56

Cem, podes dar-nos os resultados dos back tests? o meu meta está "ligeiramente" desactualizado e não consigo fazer os testes sozinha.


Presumo que nos testes uses valores de fecho de mercado, ou usas a abertura do day after?
Avatar do Utilizador
Administrador Fórum
 
Mensagens: 20972
Registado: 25/10/2002 17:02
Localização: Lisboa

por arocha » 7/4/2008 8:45

Cem ao passar o TrombaRija o Meta diz-me "More than one name in the indicator builder contains this text". E não deixa guardar. Como posso fazer?
Obrigado e um abraço.
 
Mensagens: 397
Registado: 12/12/2002 13:10

Re

por Cem pt » 7/4/2008 1:05

Eheheh, oh Lagartixa, com que então para além das tentativas de roubo do portátil também deixei de ter protecção para os gráficos?
Vais-me arranjar um belo sarilho, pois, pois, deixa-me mas é concluir rapidamente esta thread senão isto ainda vai acabar tudo numa bela pessegada!

Quanto aos restantes companheiros posso afiançar que não vou dar aqui nenhuma lição, longe disso e ainda por cima o que sei é apenas derivado da experiÊncia pessoal de trading, isto é apenas um pequeno exemplo de aplicação do conceito de princípios que enunciei, o sistema provavelmente até terá sido pouco testado e é muito natural que funcione bastante melhor com outros parÂmetros diferentes dos que vou utilizar.

Beijocas e abraços a todos.


Como é óbvio, este sistema que vou aqui deixar à vossa consideração funciona apenas para os activos que possuem volume.
Entretanto aqui fica o primeiro indicador, o da regressão linear, que lida apenas com preço e tempo.

No Metastock abram o "Indicator Builder", teclem em "New" e no respectivo título coloquem o nome:
LRS

Seguidamente façam um "Copy" dos seguintes comandos de programação e um "Paste" para o quadro da fórmula do indicador "LRS":



trendslope:=
LinRegSlope(C,31)*4+LinRegSlope(C,42)*9;

trendslopelt:=
LinRegSlope(C,155)*4+LinRegSlope(C,210)*9;

signaltrenda:=
If(
trendslope>=0 ,
1 ,
-1 ) ;

signaltrendalt:=
If(
trendslopelt>=0 ,
1 ,
-1 ) ;

signaltrendb:=
If(
trendslope > Ref(trendslope,-1)
AND
trendslope > 0 ,
1 ,
If(
trendslope < Ref(trendslope,-1)
AND
trendslope < 0 ,
-1 ,
0 )) ;

signaltrendblt:=
If(
trendslopelt > Ref(trendslopelt,-1)
AND
trendslopelt > 0 ,
1 ,
If(
trendslopelt < Ref(trendslopelt,-1)
AND
trendslopelt < 0 ,
-1 ,
0 )) ;

signaltrenddef:=
signaltrenda + signaltrendb +
signaltrendalt + signaltrendblt ;

signaltrenddef ;


Depois de carregarem no comando "OK" acabaram de guardar o indicador "LRS".

Agora vamos desenvolver o 2º indicador, o que relaciona as ponderações de volume com as médias simples das cotações.
Chamam de novo o "Indicator Builder", comando "New" e no quadro superior do título dão o seguinte nome:
PVTC

Da mesma forma façam um "Copy" dos seguintes comandos de programação e um "Paste" para o quadro da fórmula do indicador "PVTC":


movcvol42:=
Mov(C,42,VOL) ;

movcs42:=
Mov(C,42,S) ;

pvtc:=
(movcvol42 - movcs42) ;

smoothpvtc:=
Mov(pvtc,21,W) ;

signalvola:=
If(
pvtc >= 0 ,
1 ,
-1 ) ;

signalvolb:=
If(
pvtc > smoothpvtc
AND
pvtc > 0 ,
1 ,
If(
pvtc < smoothpvtc
AND
pvtc < 0 ,
-1 ,
0 )) ;

movcvol210:=
Mov(C,210,VOL) ;

movcs210:=
Mov(C,210,S) ;

pvtclt:=
(movcvol210 - movcs210) ;

smoothpvtclt:=
Mov(pvtclt,21,W) ;

signalvolalt:=
If(
pvtclt >= 0 ,
1 ,
-1 ) ;

signalvolblt:=
If(
pvtclt > smoothpvtclt
AND
pvtclt > 0 ,
1 ,
If(
pvtclt < smoothpvtclt
AND
pvtclt < 0 ,
-1 ,
0 )) ;

signalvoldef:=
signalvola + signalvolb +
signalvolalt + signalvolblt ;

signalvoldef ;


Carregam em "OK" e acabaram de guardar mais um indicador, chamado "PVTC".

Finalmente vamos juntar as partes, criando um 3º indicador relacionador que nos vai dar os verdadeiros sinais de compra e venda e eventualmente situações pontuais de reforços de compra e venda em situações consideradas particularmente favoráveis, estatisticamente falando.

Vamos novamente ao "Indicator Builder", carregamos novamente em "New" e no título colocamos:
Tromba Rija

No quadro da fórmula respectiva façam um "Copy/Paste" dos seguintes comandos:


trombarija:=
If(
FmlVar("LRS","SIGNALTRENDDEF") > 0
AND
FmlVar("PVTC","SIGNALVOLDEF") > 0 ,
1 ,
If(
FmlVar("LRS","SIGNALTRENDDEF") < 0
AND
FmlVar("PVTC","SIGNALVOLDEF") < 0 ,
-1,
PREV )) ;

signaltrombarija:=
If(
trombarija = 1
AND
FmlVar("PVTC","SIGNALVOLDEF") < 0 ,
0 ,
If(
trombarija = -1
AND
FmlVar("PVTC","SIGNALVOLDEF") > 0 ,
0 ,
If(
trombarija = 1
AND
FmlVar("LRS","SIGNALTRENDDEF") +
FmlVar("PVTC","SIGNALVOLDEF") <= 0 ,
2 ,
If(
trombarija = -1
AND
FmlVar("LRS","SIGNALTRENDDEF") +
FmlVar("PVTC","SIGNALVOLDEF") >= 0 ,
-2 ,
trombarija )))) ;

signaltrombarija ;


Carregar em "OK" e ficámos com um 3º indicador na colecção da listagem dos indicadores programados.
E pronto, para já temos concluído tudo o que precisamos por enquanto.
A seguir podemos acrescentar um "Expert" para este sistema de trading, mas isso ficará para mais tarde.
Para já deixo-vos ficar apenas com um pequeno exemplo do que nos mostra o sistema de trading do "Tromba Rija", através de um gráfico do Millennium BCP.

Cem




(Continua)
Anexos
BCP TR 20080404.png
BCP Millennium
BCP TR 20080404.png (19.94 KiB) Visualizado 9335 vezes
 
Mensagens: 3126
Registado: 4/3/2008 17:21
Localização: 16

por LUMAPICA » 7/4/2008 0:00

De facto, quanto à utilização da análise técnica, comungo das mesmas conclusões que o amigo Cem pt.
A AT é um excelente auxiliar para estudar o comportamento que as acções tiveram, o seu percurso, as suas oscilações, os seus arranques, as suas quebras etc., mas nunca poderá ser usada como um sinal credível e fiável para prever o futuro. Podemos dizer o que se passou, mas dificilmente o que se vai passar.
Eu, antes de negociar qualquer título, o indicador para o qual dou algum crédito é para o RSI., e, unicamente, para ver se está demasiado comprado ou vendido, mais nada.
Os restantes indicadores, costumo também dar uma vista de olhos, mas nunca com aquele sentido de comprar ou vender só porque deram um sinal.
Os verdadeiros sinais que me regulo, são o mercado em si e o volume do título no momento e nas sessões anteriores, quanto ao resto é como aquela máxima “foi tão bom não foi”, não tem qualquer interesse para a compra/venda.
O volume é sem margem para dúvida o indicador que mostra a força e a tendência do mercado. Grande número de transacções relativamente à média de pelo menos 60 sessões, conjuntamente com a subida da cotação é um sinal claro para comprar.
Há ainda outro indicador, embora por vezes falacioso, já que poderá ser bastante maniatado e que nos pode induzir em erro para entrar ou sair de um título: estou a falar no número de ordens de compra e venda. A legislação sobre esta parte deveria ser mais rigorosa com normas mais rígidas que não permitissem o manuseamento de um título, pelo menos naqueles pouco líquidos, já que não sou daqueles que acreditam que o mercado é controlado por dois ou três.
Bons Negócios
LUMAPICA
 
Mensagens: 41
Registado: 9/3/2008 20:18
Localização: 16

por Thunder » 6/4/2008 23:09

scpnuno Escreveu:(Caro CEM, uma vez que já tenho prazer de conhecer V.Eminencia em carne e osso e até lhe pespeguei umas beijocas, informo que os seus gráficos passaram a deixar de estar protegidos pela firewall "o-Cem-dá-cabo-de-mim-se-eu-lhes-mexo", sendo que a partir de ontem estão sujeitos ao mesmo tratamento que os do Quico, do Jaor, do Ulisses, do TRSM e outros notaveis do burgo)

Beijoca amiga



Pelo que eu posso ver continuo "safo" .... :mrgreen: e com proteção de firewall :P

Tu só gostas de dar cabo dos gráficos do DAX por isso por estar descansado :wink: ou então não .... eheheh :mrgreen:

Um abraço pro cem e uma beijoca pra ti :P
"A grandeza de um homem não está em nunca cair, mas sim em levantar-se sempre após todas as quedas." --- Confucius

"Pague a bondade com bondade, mas o mal com a justiça" --- Confucius

"Experiência e humildade são excelentes veículos para percorrer a via em direcção ao sucesso" --- Thunder o filósofo de meia-tigela
Avatar do Utilizador
 
Mensagens: 1159
Registado: 3/3/2007 16:57
Localização: Norte

por Crómio » 6/4/2008 23:06

Desde a primeira frase que a palavra volume não me saía da cabeça...

As três dimensões onde o mercado existe.
Mais simples não pode ser.

Regressão linear de curto e longo, disparo de preço e disparo de volume, simples e interessante, adivinho uma bela lição de Sistemas de Trading (esta cadeira é de que ano?).

Vou preparar o estaminé para começar a lição, peço ao mestre que se puder e se for este o intuito do tópico (posso ter entendido mal...) que coloque o código para a malta ir testando.

Um grande Obrigado,
e
Um Abraço
There are two kinds of investors: those who don't know where the market is headed, and those who don't know that they don't know.

William Bernstein
Avatar do Utilizador
 
Mensagens: 2745
Registado: 2/11/2007 16:52

por scpnuno » 6/4/2008 22:29

(Caro CEM, uma vez que já tenho prazer de conhecer V.Eminencia em carne e osso e até lhe pespeguei umas beijocas, informo que os seus gráficos passaram a deixar de estar protegidos pela firewall "o-Cem-dá-cabo-de-mim-se-eu-lhes-mexo", sendo que a partir de ontem estão sujeitos ao mesmo tratamento que os do Quico, do Jaor, do Ulisses, do TRSM e outros notaveis do burgo)

Beijoca amiga
Esta é a vantagem da ambição:
Podes não chegar á Lua
Mas tiraste os pés do chão...
Avatar do Utilizador
 
Mensagens: 3807
Registado: 6/11/2004 17:26

Sistema de trading "Tromba Rija"

por Cem pt » 6/4/2008 22:19

Preço e tempo regulam os mercados.
Estes regem-se por comportamentos cíclicos em períodos incertos, cujas subidas e descidas compõem aquilo a que designamos por tendências.
Quanto mais longos os ciclos mais estáveis serão as tendências e maiores as probabilidades de ganharmos dinheiro, se seguirmos um dos grandes 4 princípios do trading: “go with the trend”.
É um facto que existe uma grande quantidade de indicadores que consegue identificar essas tendências quando as mesmas se encontram já formadas e em andamento, falemos em médias móveis, linhas de tendência, indicadores de momentum, volatilidade, indicadores de breakout, etc.
Infelizmente todos eles possuem uma característica comum: antes de fornecer uma nova indicação de formação da tendência, tiveram que comportar perdas nas sessões que antecederam o sinal respectivo porque o mercado entretanto já invertera enquanto os indicadores ainda convergiam na indicação de declínio da tendência anterior. Estes indicadores são do tipo “passivo”: só detectam a nova tendência depois de um período inicial e da mesma se ter começado a formar.
É um contratempo, mas será que existem indicadores inversos do tipo “activo” que detectam ou antecipam novas tendências junto à sua fase de formação inicial?
De facto o ideal seria dispormos de um indicador que nos desse com algum grau de fiabilidade um sinal de proximidade do fim dessa tendência, evitando as perdas que se registam quando o indicador reconhece finalmente que está errado. Numa palavra: como evitar este risco adicional de perdas terminais de uma tendência e procurar descobrir com algum grau de probabilidade elevado o fim próximo de uma tendência?
A Análise Técnica permite dispor de algumas armas para estatisticamente detectar situações favoráveis a este tipo de questões.
Não vos vou falar de fórmulas esquisitas ou esotéricas de Gann, nem em ricochetes de Elliott e muito menos em divergências de indicadores. Esta classe de indicadores quase sempre representa apenas uma perda de força temporária das tendências em desenvolvimento, embora se reconheça a sua utilidade como meio de reforço ou auxiliar de um diagnóstico de possível fase terminal da tendência em causa.
Há no entanto um tipo simples de indicador que serve de forma fiável este propósito de ir de encontro ao indicador “activo” que procuramos desenvolver. Não é mais nem menos que um indicador de volume.
O volume pode de facto dar uma indicação preciosa ao trader: é o combustível que incendeia os mercados e que transmite o verdadeiro interesse na relação entre procura e a oferta.
Um grande volume com uma cotação a disparar num determinado sentido permite concluir que se trata de atender ou ponderar um sinal deveras importante, significa que existe um elevado consenso estabelecido e uma força significativa que procuram levar o activo em causa a um patamar de cotações que claramente não se esgota naquela sessão específica.
Se pelo contrário uma determinada acção aumentou de forma significativa mas com pouco volume, desconfiem: normalmente o mercado acabará por corrigir e voltar a um nível próximo do ponto de partida dentro de mais umas quantas sessões.
Dispondo deste conhecimento básico, resta-nos procurar desenvolver este conceito através de um sistema de trading que procure traduzir estes princípios.
Caso tenham o programa de Metastock, aqui fica à vossa disposição um sistema de negociação que se baseia nestes princípios e que procura ser o resultado dos outputs de 2 “custom indicators” diferentes: um baseado numa regressão linear de médio e longo prazo e outro numa relação de volumes igualmente de médio e longo prazo.
Apresento-vos o sistema de trading “Tromba Rija”!

Cem




(Continua)
 
Mensagens: 3126
Registado: 4/3/2008 17:21
Localização: 16

Anterior

Quem está ligado:
Utilizadores a ver este Fórum: Carlos73, Cem pt, Google [Bot], Google Adsense [Bot], hugob0ss, iniciado1, jvrs, macau5m, PAULOJOAO, Sr.Marques e 134 visitantes